SCREEN 13
DEFINT A-Z
speed1 = 0 'pipes
speed2 = 0  'large vertical bars
speed3 = 0  'fan
RANDOMIZE TIMER

'--load palette----
LOCATE 12, 2
PRINT "Please Wait.  Colors are Loading..."
PRINT "   Press any key to Exit Program"
FOR kolors = 1 TO 10
READ lo, hi, rd, gr, bl, r, g, b
FOR hues = lo TO hi
   IF INKEY$ <> "" THEN END
   h& = rd + (256 * gr) + (65536 * bl)
   PALETTE hues, h&
   rd = rd + r
   gr = gr + g
   bl = bl + b
NEXT hues
NEXT kolors

'---metallic vertical & horizontal bars---
WINDOW (0, 0)-(640, 480)        'reduce size of bars
LINE (0, 0)-(640, 480), 7, BF   'background color
col1 = 10: row1 = 10
row2 = 470: yes = 0: kolor = 18
FOR sets = 1 TO 20
   FOR pipes = 1 TO 5
      FOR shades = 1 TO 42
         IF INKEY$ <> "" THEN END
         kolor = kolor + 1
         '---------------------------------
         IF yes = 0 THEN
         col1 = col1 + 1: col2 = col1
         ELSE row1 = row1 + 1: row2 = row1
         END IF
         LINE (col1, row1)-(col2, row2), kolor
         '-------------------------------------
         FOR delay = 1 TO speed1
         NEXT delay
      NEXT shades
      col1 = RND * 650: row1 = RND * 500
      row2 = RND * 500: yes = INT(RND * 2)
   NEXT pipes
   kolor = 16
NEXT sets

'-five metallic bars---
col1 = 10: kolor = 19
WINDOW (0, 0)-(320, 200)
FOR j = 1 TO 210
   IF INKEY$ <> "" THEN END
   LINE (col1, 0)-(col1, 480), kolor
   col1 = col1 + 1: kolor = kolor + 1
   IF j = 42 OR j = 84 OR j = 126 OR j = 168 THEN col1 = col1 + 21
   FOR delay = 1 TO speed2
   NEXT delay
NEXT j
SLEEP 1

'---white/yellow/red/blue curtain---
col1 = 320: row1 = 0: col2 = 0: row2 = 200: kolor1 = 214
c = -1: d = 0: e = 1: f = 0: g = 320: kolor = 16
FOR l = 1 TO 2
   FOR m = 1 TO g
      IF INKEY$ <> "" THEN END
      LINE (col1, row1)-(col2, row2), kolor
      LINE (col1, row1 + 1)-(col2, row2 + 1), kolor
      col1 = col1 + c: row1 = row1 + d
      col2 = col2 + e: row2 = row2 + f
      kolor = kolor + 1
      FOR delay = 1 TO speed3
      NEXT delay
      IF m = kolor1 THEN kolor = 16
   NEXT m
   col1 = 0: row1 = 0: col2 = 320: row2 = 200: kolor = 121
   c = 0: d = 1: e = 0: f = -1: g = 200: kolor1 = 110
NEXT l
SLEEP 2

'--erase colors----
FOR kolor = 1 TO 230
PALETTE kolor, 0
FOR delay = 1 TO speed2
NEXT delay
NEXT kolor
CLS : PALETTE
END


'load colors
DATA 16, 37, 0, 0, 0, 3, 3, 3
DATA 38, 58, 63, 63, 63, -3, -3, -3
DATA 59, 80, 0, 0, 0, 3, 3, 0
DATA 81, 101, 63, 63, 0, -3, -3, 0
DATA 102, 123, 0, 0, 0, 3, 0, 0
DATA 124, 144, 63, 0, 0, -3, 0, 0
DATA 145, 166, 0, 0, 0, 0, 3, 0
DATA 167, 187, 0, 63, 0, 0, -3, 0
DATA 188, 209, 0, 0, 0, 0, 0, 3
DATA 210, 230, 0, 0, 63, 0, 0, -3