10 CLS
20 INPUT "DO YOU WANT TO KNOW HOW TO PLAY (Y/N)"; K$
30 IF K$ = "Y" THEN GOSUB 780
40 CLS
50 'game starts
60 PRINT ">Politics"
70 PRINT
80 PRINT "(c) 1982 by Mike Ault":PRINT
90 B=1.000000E+05:T=0:N=0
100 INPUT "HIT RETURN...";K$
110 CLS:PRINT "BUDGET:$";B:IF B < 0 THEN GOTO 450
120 T=T+1:IF T>10 THEN 300
130 RANDOMIZE TIMER
140 X=INT(RND*22)+1:RESTORE
150 FOR I=1 TO X:READ P$,C:NEXT I
160 PRINT:PRINT P$:PRINT:PRINT "Estimated cost: $";C
170 PRINT:PRINT "Do you want to spend the money (Y/N)";
180 INPUT K$
190 IF K$= "Y" THEN 230
200 N=N+1:IF N > RND * 10 THEN 380
210 IF RND > 9.200000E-01 THEN GOSUB 270
220 GOTO 100
230 A=INT(RND*(C/10)):IF RND > 8.000000E-01 THEN A= -A
240 C=C+A:PRINT "Actual cost: $";C:B = B - C
250 IF RND > 4.900000E-01 THEN GOSUB 270
260 GOTO 100
270 PRINT "Voters elect to increase your budget!!!"
280 E=INT(RND *1000) + 500:B=B+E
290 RETURN
300 CLS
310 PRINT "Elections!":PRINT "It's you against the old dogcather!"
320 PRINT:PRINT "Votes: ": YV=INT(RND *1000)+500 +15*(20-N):DV=2000-YV
330 PRINT:PRINT "For you :";YV:PRINT "For dogcather :";DV
340 PRINT:IF DV<YV THEN PRINT "You won!!! Nice going, I knew you could do it.":                       GOTO 480
350 IF DV=YV THEN 300
360 PRINT "Well, it looks like you lost."
370 PRINT "Better luck next time.":GOTO 480
380 PRINT "Voters unanimously decide to kick you out of office!"
390 PRINT "You're in trouble!"
400 FOR I=1 TO 1000:NEXT I
410 IF RND <5.000000E-01 THEN GOTO 530
420 PRINT "The voters may not like you as mayor,"
430 PRINT "but they find you a new job."
440 PRINT "Everyone thinks you're a terrific dogcather!":GOTO 480
450 PRINT "There's no money left."
460 PRINT "The voters kick you out and elect the town dogcather mayor."
470 PRINT "You rellay screwed up this time!":GOTO 490
480 PRINT:PRINT "You had $";B;"money left."
490 PRINT:PRINT "Play again";
500 INPUT K$
510 IF K$ = "Y" THEN CLS:GOTO 90
520 PRINT "Thanks for playing.":END
530 PRINT "Luckily you manged to grab what was left in the budget";
540 PRINT "and escape to sunny Bermuda."
550 GOTO 480
560 DATA The little leage team needs new uniforms.,500
570 DATA A flood hits town!! Damage to streets.,20000
580 DATA The fire house just burnd down! We need a new one.,30000
590 DATA A truck crashed into town hall! Repairs are necessary.,5000
600 DATA The town computer broke down-we need to hire a repair man.,1000
610 DATA The voters want a statue put up to honor the town dogcather.,15000
620 DATA The voters demand you build a town park.,50000
630 DATA The town dogcather needs a new truck and more nets.,10000
640 DATA The libray needs to replace stolen books.,8000
650 DATA The police force wants a new fleet of cruisers.,45000
660 DATA The voters demand that you repair the pothole-ridden streets.,1500
670 DATA The dogcather goes on strike to demand more pay.,5000
680 DATA The voters want the trees trimed on the public streets.,7000
690 DATA The police force wants to train new officers in water balet.,10000
700 DATA The fire department wants to repaint the hook and ladder trucks.,1500
710 DATA The town dump wants to buy a new trash compactor uint.,20000
720 DATA The roads in front of town hall need repaving.,10000
730 DATA The street lamps all need new bulbs.,9000
740 DATA The town wants new street sings put up at every corner.,15000
750 DATA Town overrun with peokey petunias! Voters demand you destroy  them.,35000
760 DATA The dogcather wants a vacation in Hawai.,5000
770 DATA Students lead protest to demand better food in school cafeteria.,10000
780 CLS:PRINT
790 PRINT "In this game you are the mayor of a small town."
800 PRINT:PRINT "You must decide how to spend your budget"
810 PRINT "to deal with the promlems that com up."
820 PRINT "Your object is to please the voters so you can be re-elected."
830 PRINT:PRINT "You start with 100000 in your budget."
840 PRINT
850 INPUT "Hit return...";K$
860 RETURN